add keybind and function to unload unit's weapon/muzzle

- add keybind and function to unload unit's weapon/muzzle - requires CBATeam/CBA_A3#1527
Drofseh · Dec 11, 2021 · b438e43 · b438e43
1 parent e0df864
commit b438e43
Show file tree

Hide file tree

Showing 4 changed files with 108 additions and 0 deletions.
diff --git a/addons/common/XEH_PREP.hpp b/addons/common/XEH_PREP.hpp
@@ -187,6 +187,7 @@ PREP(uniqueElements);
 PREP(uniqueItems);
 PREP(unloadPerson);
 PREP(unloadPersonLocal);
+PREP(unloadWeaponMan);
 PREP(unmuteUnit);
 PREP(useItem);
 PREP(useMagazine);

diff --git a/addons/common/XEH_postInit.sqf b/addons/common/XEH_postInit.sqf
@@ -527,4 +527,21 @@ GVAR(deviceKeyCurrentIndex) = -1;
 {false},
 [0xC7, [true, false, false]], false] call CBA_fnc_addKeybind;  //SHIFT + Home Key
 
+
+["ACE3 Weapons", QGVAR(unloadWeapon), localize LSTRING(unloadWeapon), {
+    // Conditions:
+    if !([ACE_player, objNull, ["isNotInside"]] call FUNC(canInteractWith)) exitWith {false};
+
+    private _currentWeapon = currentWeapon ACE_player;
+    if !(_currentWeapon != primaryWeapon _unit && {_currentWeapon != handgunWeapon _unit} && {_currentWeapon != secondaryWeapon _unit}) exitWith {false};
+
+    private _currentMuzzle = currentMuzzle ACE_player;
+    private _currentAmmoCount = ACE_player ammo _currentMuzzle;
+    if (_currentAmmoCount < 1) exitWith {false};
+
+    // Statement:
+    [ACE_player, _currentWeapon, _currentMuzzle, _currentAmmoCount, false] call FUNC(unloadWeaponMan);
+    true
+}, {false}, [19, [false, false, true]], false] call CBA_fnc_addKeybind; //ALT + R Key
+
 GVAR(commonPostInited) = true;
diff --git a/addons/common/functions/fnc_unloadWeaponMan.sqf b/addons/common/functions/fnc_unloadWeaponMan.sqf
@@ -0,0 +1,87 @@
+#include "script_component.hpp"
+/*
+ * Author: drofseh & Commy2
+ * Unload the magazine from the unit's weapon and attempt to put it in a sensible place.
+ *
+ * Arguments:
+ * 0: Player <OBJECT>
+ * 1: Weapon <STRING>
+ * 2: Muzzle (optional, default: Weapon)<STRING>
+ * 3: Ammo count (optional, default: ammo currentMuzzle Player) <NUMBER>
+ * 4: Skip animation? (optional, default: false) <BOOL>
+ *
+ * Return Value:
+ * None
+ *
+ * Example:
+ * [ACE_player, currentWeapon ACE_player, currentMuzzle ACE_player, 23, false] call ace_common_fnc_unloadWeaponMan
+ *
+ * Public: No
+ */
+
+params ["_unit", "_weapon", ["_muzzle", _weapon], ["_ammoCount", ammo _muzzle _unit], ["_skipAnim", false]];
+TRACE_5("params",_unit,_weapon,_muzzle,_ammoCount,_skipAnim);
+
+// audiovisual effects
+private _delay = 0;
+if !(_skipAnim) then {
+    _delay = 1.5;
+    private _config = configFile >> "CfgWeapons" >> _weapon;
+    if (_weapon != _muzzle) then {
+        _config = _config >> _muzzle;
+    };
+
+    // get and play animation
+    private _unloadAction = getText (_config >> "ACE_unloadAction");
+
+    if (_unloadAction == "") then {
+        _unloadAction = getText (_config >> "reloadAction");
+    };
+
+    [_unit, _unloadAction, 1] call FUNC(doGesture);
+
+    // get and play sound
+    private _unloadSound = getText (_config >> "ACE_unloadSound");
+
+    if (_unloadSound == "") then {
+        _unloadSound = "A3\Sounds_F\arsenal\weapons\Rifles\Katiba\reload_Katiba.wss";
+        private _unloadSoundArray = getArray (_config >> "reloadMagazineSound");
+
+        // file extention is required for playSound3D
+        if (_unloadSoundArray isNotEqualTo []) then {
+            private _wssTest = format ["%1.wss", _unloadSoundArray select 0];
+            if (fileExists _wssTest) then {
+                _unloadSound = _wssTest;
+            } else {
+                private _wavTest = format ["%1.wav", _unloadSoundArray select 0];
+                if (fileExists _wavTest) then {
+                    _unloadSound = _wavTest;
+                };
+            };
+        };
+    };
+
+    playSound3D [_unloadSound, _unit];
+};
+
+// remove magazine from weapon and add it to inventory
+[{
+    params ["_unit", "_weapon", "_ammoCount"];
+
+    // remove weapon item
+    private _magazineClass = currentMagazine _unit;
+
+    switch true do {
+        case (_weapon == primaryWeapon _unit): {
+            _unit removePrimaryWeaponItem _magazineClass;
+        };
+        case (_weapon == handgunWeapon _unit): {
+            _unit removeHandgunItem _magazineClass;
+        };
+        case (_weapon == secondaryWeapon _unit): {
+            _unit removeSecondaryWeaponItem _magazineClass;
+        };
+    };
+
+    [_unit, _magazineClass, _ammoCount, true] call CBA_fnc_addMagazine;
+}, [_unit, _weapon, _ammoCount], _delay] call CBA_fnc_waitAndExecute;
diff --git a/addons/common/stringtable.xml b/addons/common/stringtable.xml
@@ -1590,5 +1590,8 @@
             <Chinese>受所在位置影響提升醫療能力</Chinese>
             <Turkish>Konumlar Tedaviyi Hızlandırır</Turkish>
         </Key>
+        <Key ID="STR_ACE_Common_unloadWeapon">
+            <English>Unload Weapon</English>
+        </Key>
     </Package>
 </Project>