Medical Vitals - Add SPO2

addons/advanced_fatigue/functions/fnc_mainLoop.sqf

@@ -23,6 +23,8 @@ if (!alive ACE_player) exitWith {
     _staminaBarContainer ctrlCommit 1;
 };
 
+private _oxygen = (ACE_player getVariable [QEGVAR(medical,spo2), 90]) / 100;
+
 private _currentWork = REE;
 private _currentSpeed = (vectorMagnitude (velocity ACE_player)) min 6;
 
@@ -42,8 +44,8 @@ GVAR(muscleDamage) = (GVAR(muscleDamage) + (_currentWork / GVAR(peakPower)) ^ 3.
 private _muscleIntegritySqrt = sqrt (1 - GVAR(muscleDamage));
 
 // Calculate available power
-private _ae1PathwayPowerFatigued = GVAR(ae1PathwayPower) * sqrt (GVAR(ae1Reserve) / AE1_MAXRESERVE) * OXYGEN * _muscleIntegritySqrt;
-private _ae2PathwayPowerFatigued = GVAR(ae2PathwayPower) * sqrt (GVAR(ae2Reserve) / AE2_MAXRESERVE) * OXYGEN * _muscleIntegritySqrt;
+private _ae1PathwayPowerFatigued = GVAR(ae1PathwayPower) * sqrt (GVAR(ae1Reserve) / AE1_MAXRESERVE) * _oxygen * _muscleIntegritySqrt;
+private _ae2PathwayPowerFatigued = GVAR(ae2PathwayPower) * sqrt (GVAR(ae2Reserve) / AE2_MAXRESERVE) * _oxygen * _muscleIntegritySqrt;
 
 // Calculate how much power is consumed from each reserve
 private _ae1Power = _currentWork min _ae1PathwayPowerFatigued;
@@ -58,8 +60,8 @@ GVAR(anReserve)  = GVAR(anReserve)  -  _anPower / WATTSPERATP;
 GVAR(anFatigue)  = GVAR(anFatigue) + _anPower * (0.057 / GVAR(peakPower)) * 1.1;
 
 // Aerobic ATP reserve recovery
-GVAR(ae1Reserve) = ((GVAR(ae1Reserve) + OXYGEN * 6.60 * (GVAR(ae1PathwayPower) - _ae1Power) / GVAR(ae1PathwayPower) * GVAR(recoveryFactor)) min AE1_MAXRESERVE) max 0;
-GVAR(ae2Reserve) = ((GVAR(ae2Reserve) + OXYGEN * 5.83 * (GVAR(ae2PathwayPower) - _ae2Power) / GVAR(ae2PathwayPower) * GVAR(recoveryFactor)) min AE2_MAXRESERVE) max 0;
+GVAR(ae1Reserve) = ((GVAR(ae1Reserve) + _oxygen * 6.60 * (GVAR(ae1PathwayPower) - _ae1Power) / GVAR(ae1PathwayPower) * GVAR(recoveryFactor)) min AE1_MAXRESERVE) max 0;
+GVAR(ae2Reserve) = ((GVAR(ae2Reserve) + _oxygen * 5.83 * (GVAR(ae2PathwayPower) - _ae2Power) / GVAR(ae2PathwayPower) * GVAR(recoveryFactor)) min AE2_MAXRESERVE) max 0;
 
 // Anaerobic ATP reserver and fatigue recovery
 GVAR(anReserve) = ((GVAR(anReserve)
@@ -70,9 +72,9 @@ GVAR(anFatigue) = ((GVAR(anFatigue)
     - (_ae1PathwayPowerFatigued + _ae2PathwayPowerFatigued - _ae1Power - _ae2Power) * (0.057 / GVAR(peakPower)) * GVAR(anFatigue) ^ 2 * GVAR(recoveryFactor)
 ) min 1) max 0;
 
-private _aeReservePercentage = (GVAR(ae1Reserve) / AE1_MAXRESERVE + GVAR(ae2Reserve) / AE2_MAXRESERVE) / 2;
-private _anReservePercentage = GVAR(anReserve) / AN_MAXRESERVE;
-private _perceivedFatigue = 1 - (_anReservePercentage min _aeReservePercentage);
+GVAR(aeReservePercentage) = (GVAR(ae1Reserve) / AE1_MAXRESERVE + GVAR(ae2Reserve) / AE2_MAXRESERVE) / 2;
+GVAR(anReservePercentage) = GVAR(anReserve) / AN_MAXRESERVE;
+private _perceivedFatigue = 1 - (GVAR(anReservePercentage) min GVAR(aeReservePercentage));
 
 [ACE_player, _perceivedFatigue, _currentSpeed, GVAR(anReserve) == 0] call FUNC(handleEffects);
 

addons/medical_engine/script_macros_medical.hpp

@@ -42,6 +42,7 @@
 #define GET_ARRAY(config,default) (if (isArray (config)) then {getArray (config)} else {default})
 
 #define DEFAULT_HEART_RATE 80
+#define DEFAULT_SPO2 97
 #define DEFAULT_PERIPH_RES 100
 
 // --- blood
@@ -141,6 +142,7 @@
 #define VAR_WOUND_BLEEDING    QEGVAR(medical,woundBleeding)
 #define VAR_CRDC_ARRST        QEGVAR(medical,inCardiacArrest)
 #define VAR_HEART_RATE        QEGVAR(medical,heartRate)
+#define VAR_SPO2              QEGVAR(medical,spo2)
 #define VAR_PAIN              QEGVAR(medical,pain)
 #define VAR_PAIN_SUPP         QEGVAR(medical,painSuppress)
 #define VAR_PERIPH_RES        QEGVAR(medical,peripheralResistance)
@@ -163,6 +165,7 @@
 #define GET_BLOOD_VOLUME(unit)      (unit getVariable [VAR_BLOOD_VOL, DEFAULT_BLOOD_VOLUME])
 #define GET_WOUND_BLEEDING(unit)    (unit getVariable [VAR_WOUND_BLEEDING, 0])
 #define GET_HEART_RATE(unit)        (unit getVariable [VAR_HEART_RATE, DEFAULT_HEART_RATE])
+#define GET_SPO2(unit)              (unit getVariable [VAR_SPO2, DEFAULT_SPO2])
 #define GET_HEMORRHAGE(unit)        (unit getVariable [VAR_HEMORRHAGE, 0])
 #define GET_PAIN(unit)              (unit getVariable [VAR_PAIN, 0])
 #define GET_PAIN_SUPPRESS(unit)     (unit getVariable [VAR_PAIN_SUPP, 0])

addons/medical_vitals/CfgVehicles.hpp

@@ -0,0 +1,6 @@
+class CfgWeapons {
+    class H_HelmetB;
+    class H_PilotHelmetFighter_B: H_HelmetB {
+        GVAR(oxygenSupply) = QUOTE(vehicle _this isKindOf 'Plane' || vehicle _this isKindOf 'Helicopter');
+    };
+};

addons/medical_vitals/XEH_PREP.hpp

@@ -1,4 +1,5 @@
 PREP(handleUnitVitals);
 PREP(updateHeartRate);
+PREP(updateOxygen);
 PREP(updatePainSuppress);
 PREP(updatePeripheralResistance);

addons/medical_vitals/config.cpp

@@ -22,5 +22,6 @@ class CfgPatches {
 };
 
 #include "CfgEventHandlers.hpp"
+#include "CfgVehicles.hpp"
 
 #endif

addons/medical_vitals/functions/fnc_handleUnitVitals.sqf

@@ -31,6 +31,9 @@ if (_syncValues) then {
     _unit setVariable [QGVAR(lastMomentValuesSynced), CBA_missionTime];
 };
 
+// Update SPO2 intake and usage since last update
+[_unit, _deltaT, _syncValues] call FUNC(updateOxygen);
+
 private _bloodVolume = GET_BLOOD_VOLUME(_unit) + ([_unit, _deltaT, _syncValues] call EFUNC(medical_status,getBloodVolumeChange));
 _bloodVolume = 0 max _bloodVolume min DEFAULT_BLOOD_VOLUME;
 

addons/medical_vitals/functions/fnc_updateHeartRate.sqf

@@ -37,6 +37,7 @@ if IN_CRDC_ARRST(_unit) then {
     if (_bloodVolume > BLOOD_VOLUME_CLASS_4_HEMORRHAGE) then {
         GET_BLOOD_PRESSURE(_unit) params ["_bloodPressureL", "_bloodPressureH"];
         private _meanBP = (2/3) * _bloodPressureH + (1/3) * _bloodPressureL;
+        private _spo2 = GET_SPO2(_unit);
         private _painLevel = GET_PAIN_PERCEIVED(_unit);
 
         private _targetBP = 107;
@@ -51,8 +52,11 @@ if IN_CRDC_ARRST(_unit) then {
         if (_painLevel > 0.2) then {
             _targetHR = _targetHR max (80 + 50 * _painLevel);
         };
+        // Increase HR to compensate for low blood oxygen
+        // Increase HR to compensate for higher oxygen demand (e.g. running, recovering from sprint)
+        private _oxygenDemand = _unit getVariable [QGVAR(oxygenDemand), 0];
+        _targetHR = _targetHR + ((97 - _spo2) * 2) + (_oxygenDemand * -1000);
         _targetHR = (_targetHR + _hrTargetAdjustment) max 0;
-
         _hrChange = round(_targetHR - _heartRate) / 2;
     } else {
         _hrChange = -round(_heartRate / 10);

addons/medical_vitals/functions/fnc_updateOxygen.sqf

@@ -0,0 +1,81 @@
+#include "script_component.hpp"
+/*
+ * Author: Brett Mayson
+ * Update the oxygen levels
+ *
+ * Arguments:
+ * 0: The Unit <OBJECT>
+ * 1: Time since last update <NUMBER>
+ * 2: Sync value? <BOOL>
+ *
+ * ReturnValue:
+ * Current SPO2 <NUMBER>
+ *
+ * Example:
+ * [player, 1, false] call ace_medical_vitals_fnc_updateOxygen
+ *
+ * Public: No
+ */
+
+params ["_unit", "_deltaT", "_syncValue"];
+
+#define IDEAL_PPO2 0.255
+
+private _current = GET_SPO2(_unit);
+private _heartRate = GET_HEART_RATE(_unit);
+
+private _altitude = EGVAR(common,mapAltitude) + ((getPosASL _unit) select 2);
+private _po2 = if (missionNamespace getVariable ["ace_weather", false]) then {
+    private _temperature = _altitude call EFUNC(weather,calculateTemperatureAtHeight);
+    private _pressure = _altitude call EFUNC(weather,calculateBarometricPressure);
+    [_temperature, _pressure, EGVAR(weather,currentHumidity)] call EFUNC(weather,calculateOxygenDensity)
+} else {
+    // Rough approximation of the partial pressure of oxygen in the air
+    0.25725 * (_altitude / 1000 + 1)
+};
+
+private _oxygenSaturation = (IDEAL_PPO2 min _po2) / IDEAL_PPO2;
+
+// Check gear for oxygen supply
+[goggles _unit, headgear _unit] findIf {
+    if (_x != "") then {
+        if (isNil QGVAR(oxygenSupplyConditionCache)) then {
+            GVAR(oxygenSupplyConditionCache) = createHashmap;
+        };
+        private _condition = GVAR(oxygenSupplyConditionCache) getOrDefaultCall [_x, {
+            compile getText (configFile >> "CfgWeapons" >> _x >> QGVAR(oxygenSupply))
+        }, true];
+        if (_condition isNotEqualTo {} && {ACE_player call _condition}) then {
+            _oxygenSaturation = 1;
+            _po2 = IDEAL_PPO2;
+            true
+        } else {
+            false
+        }
+    } else {
+        false
+    }
+};
+
+// Base oxygen consumption rate
+private _negativeChange = BASE_OXYGEN_USE;
+
+// Fatigue will demand more oxygen
+if (_unit == player && {missionNamespace getVariable [QEGVAR(advanced_fatigue,enabled), false]}) then {
+    _negativeChange = _negativeChange - ((1 - EGVAR(advanced_fatigue,aeReservePercentage)) * 0.5);
+};
+
+// Effectiveness of capturing oxygen
+// increases slightly as po2 starts lowering
+// but falls off quickly as po2 drops further
+private _capture = 1 max ((_po2 / IDEAL_PPO2) ^ (-_po2 * 3));
+private _positiveChange = _heartRate * 0.00368 * _oxygenSaturation * _capture;
+
+private _breathingEffectiveness = 1;
+
+private _rateOfChange = _negativeChange + (_positiveChange * _breathingEffectiveness);
+
+private _spo2 = (_current + (_rateOfChange * _deltaT)) max 0 min 100;
+
+_unit setVariable [QGVAR(oxygenDemand), _negativeChange - BASE_OXYGEN_USE];
+_unit setVariable [VAR_SPO2, _spo2, _syncValue];

addons/medical_vitals/script_component.hpp

@@ -16,3 +16,5 @@
 
 #include "\z\ace\addons\medical_engine\script_macros_medical.hpp"
 #include "\z\ace\addons\main\script_macros.hpp"
+
+#define BASE_OXYGEN_USE -0.25

addons/weather/XEH_PREP.hpp

@@ -1,9 +1,9 @@
-
 PREP(calculateAirDensity);
 PREP(calculateBarometricPressure);
 PREP(calculateDensityAltitude);
 PREP(calculateDewPoint);
 PREP(calculateHeatIndex);
+PREP(calculateOxygenDensity);
 PREP(calculateRoughnessLength);
 PREP(calculateSpeedOfSound);
 PREP(calculateTemperatureAtHeight);

addons/weather/functions/fnc_calculateOxygenDensity.sqf

@@ -0,0 +1,20 @@
+#include "script_component.hpp"
+/*
+ * Author: Brett Mayson
+ * Calculates the oxygen density
+ *
+ * Arguments:
+ * 0: temperature - degrees celsius <NUMBER>
+ * 1: pressure - hPa <NUMBER>
+ * 2: relativeHumidity - value between 0.0 and 1.0 <NUMBER>
+ *
+ * Return Value:
+ * density of oxygen - kg * m^(-3) <NUMBER>
+ *
+ * Example:
+ * [0, 1020] call ace_weather_fnc_calculateOxygenDensity
+ *
+ * Public: No
+ */
+
+(_this call FUNC(calculateAirDensity)) * 0.21